100'SAVE"KEYHIT.BAS"
110CLEAR :CR=0:MX=10:MY=6
120DIM GM(MX,MY)
130CT=10:SC=0:CC=10:CK=0:CLS
150LOCATE MX+1,0:PRINT "- KEYHITTER -"
160FOR I=0 TO 5:LOCATE MX,I:PRINT "|";:NEXT
170GOSUB *DSC
180*ST
190FOR I=0 TO 3
200IF I=3 LOCATE MX+3:PRINT "START!" ELSE LOCATE MX+5,4:PRINT STR$ (3-I)
210FOR J=0 TO 1000:NEXT
220NEXT
230LOCATE MX+3,4:PRINT "      "
240*MAIN
250IF CT>=CC LET X= RND MX-1:Y= RND MY-1:CT=0:CK=1 ELSE X=0:Y=0:CT=CT+1
260IF GM(X,Y)=0 AND CT=0 LET GM(X,Y)=65+ RND 26-1:CR=CR+1:LOCATE X,Y:PRINT CHR$ GM(X,Y);
270IF CR>=MX*MY LOCATE MX+2,2:PRINT "GAME OVER":END
280Z= ASC INKEY$ :IF Z=0 GOTO *MAIN
290I=0
300*CLP
310X=I MOD MX:Y=I/MX
320IF GM(X,Y)=Z LET GM(X,Y)=0:CR=CR-1:LOCATE X,Y:PRINT " ";:SC=SC+10:GOSUB *DSC ELSE IF I<MX*MY LET I=I+1:GOTO *CLP ELSE SC=SC-5:GOSUB *DSC
330IF CR>0 OR CK<>1 GOTO *MAIN
340LOCATE MX+2,3:IF CC=1 PRINT "ALL CLEAR!" ELSE PRINT "CLEAR!"
350SC=SC+100:GOSUB *DSC
360IF CC=3 LOCATE MX+1,4:PRINT "END":END
370LOCATE MX+2,5:PRINT "HIT KEY!"
380WHILE INKEY$ <>"":WEND :WHILE INKEY$ ="":WEND
400CT=0:CC=CC-1:CR=0:CK=0:SC=SC+5
410LOCATE MX+2,3:PRINT "      "
420LOCATE MX+2,5:PRINT "        "
430GOTO *ST
440*DSC
450LOCATE MX+1,1:PRINT "Lv"; HEX$ (11-CC);" ½º±:"; STR$ SC;"  "
460RETURN